mirror of
https://github.com/postgres/postgres.git
synced 2026-04-23 07:07:22 -04:00
379695d3cc
pgp_pub_decrypt_bytea() was missing a safeguard for the session key length read from the message data, that can be given in input of pgp_pub_decrypt_bytea(). This can result in the possibility of a buffer overflow for the session key data, when the length specified is longer than PGP_MAX_KEY, which is the maximum size of the buffer where the session data is copied to. A script able to rebuild the message and key data that can trigger the overflow is included in this commit, based on some contents provided by the reporter, heavily editted by me. A SQL test is added, based on the data generated by the script. Reported-by: Team Xint Code as part of zeroday.cloud Author: Michael Paquier <michael@paquier.xyz> Reviewed-by: Noah Misch <noah@leadboat.com> Security: CVE-2026-2005 Backpatch-through: 14
114 lines
2 KiB
Meson
114 lines
2 KiB
Meson
# Copyright (c) 2022-2026, PostgreSQL Global Development Group
|
|
|
|
if not ssl.found()
|
|
subdir_done()
|
|
endif
|
|
|
|
pgcrypto_sources = files(
|
|
'crypt-blowfish.c',
|
|
'crypt-des.c',
|
|
'crypt-gensalt.c',
|
|
'crypt-md5.c',
|
|
'crypt-sha.c',
|
|
'mbuf.c',
|
|
'pgcrypto.c',
|
|
'pgp-armor.c',
|
|
'pgp-cfb.c',
|
|
'pgp-compress.c',
|
|
'pgp-decrypt.c',
|
|
'pgp-encrypt.c',
|
|
'pgp-info.c',
|
|
'pgp-mpi.c',
|
|
'pgp-pgsql.c',
|
|
'pgp-pubdec.c',
|
|
'pgp-pubenc.c',
|
|
'pgp-pubkey.c',
|
|
'pgp-s2k.c',
|
|
'pgp.c',
|
|
'px-crypt.c',
|
|
'px-hmac.c',
|
|
'px.c',
|
|
)
|
|
|
|
pgcrypto_regress = [
|
|
'init',
|
|
'md5',
|
|
'sha1',
|
|
'hmac-md5',
|
|
'hmac-sha1',
|
|
'blowfish',
|
|
'rijndael',
|
|
'sha2',
|
|
'des',
|
|
'3des',
|
|
'cast5',
|
|
'crypt-des',
|
|
'crypt-md5',
|
|
'crypt-blowfish',
|
|
'crypt-xdes',
|
|
'pgp-armor',
|
|
'pgp-decrypt',
|
|
'pgp-encrypt',
|
|
'pgp-encrypt-md5',
|
|
'pgp-pubkey-decrypt',
|
|
'pgp-pubkey-encrypt',
|
|
'pgp-pubkey-session',
|
|
'pgp-info',
|
|
'crypt-shacrypt'
|
|
]
|
|
|
|
pgcrypto_openssl_sources = files(
|
|
'openssl.c',
|
|
'pgp-mpi-openssl.c',
|
|
)
|
|
|
|
pgcrypto_deps = []
|
|
pgcrypto_link_with = []
|
|
|
|
pgcrypto_deps += ssl
|
|
pgcrypto_sources += pgcrypto_openssl_sources
|
|
|
|
if zlib.found()
|
|
pgcrypto_deps += zlib
|
|
pgcrypto_regress += 'pgp-compression'
|
|
else
|
|
pgcrypto_regress += 'pgp-zlib-DISABLED'
|
|
endif
|
|
|
|
if host_system == 'windows'
|
|
pgcrypto_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
|
|
'--NAME', 'pgcrypto',
|
|
'--FILEDESC', 'pgcrypto - cryptographic functions',])
|
|
endif
|
|
|
|
pgcrypto = shared_module('pgcrypto',
|
|
pgcrypto_sources,
|
|
link_with: pgcrypto_link_with,
|
|
c_pch: pch_postgres_h,
|
|
kwargs: contrib_mod_args + {
|
|
'dependencies': [pgcrypto_deps, contrib_mod_args['dependencies']]
|
|
},
|
|
)
|
|
contrib_targets += pgcrypto
|
|
|
|
install_data(
|
|
'pgcrypto--1.0--1.1.sql',
|
|
'pgcrypto--1.1--1.2.sql',
|
|
'pgcrypto--1.2--1.3.sql',
|
|
'pgcrypto--1.3.sql',
|
|
'pgcrypto--1.3--1.4.sql',
|
|
'pgcrypto.control',
|
|
kwargs: contrib_data_args,
|
|
)
|
|
|
|
|
|
tests += {
|
|
'name': 'pgcrypto',
|
|
'sd': meson.current_source_dir(),
|
|
'bd': meson.current_build_dir(),
|
|
'regress': {
|
|
'sql': [
|
|
pgcrypto_regress,
|
|
],
|
|
},
|
|
}
|